Yes, it is possible, but you need the Altiris component for Backup Exec System Recovery. (Referred to as BESR-S). This software was built specifically for what you need it for.

If you contact the sales line, they can direct you to the proper channels to obtaining this software.

Andreas,

BESR-S is for Altiris Notification Server which I don't have. I only have Deployment Server.
Is there anthoer why I can silently install the license key??

james -- i have two VBS scripts that i use to install BESR license keys.  The only difference is that one takes the computer name as a command line argument, the other takes a text file name as a command line argument.  The text file contains a list of computers (each on its own line) to install the license key to.  When editing the scripts to reflect your own license key, omit the dashes or the license key installation will fail.  Both scripts will report if they can connect to the remote computer and if the license key installation was successful.  The script has to be run from a server or worstation that has BESR installed.

'===============================================================
'InstallLicense.vbs

' Sample usage: Cscript.exe InstallLicense.vbs "MyFileServer"

Option Explicit

Dim sServerName, sLicenseKey
Dim oV2iAuto

'Set License Key -- Omit dashes when editing this variable

sLicenseKey = "0000000000000000"

'Set Server Name

If (WScript.Arguments.Count < 1) Then
WScript.Echo "Usage: cscript.exe InstallLicense.vbs [Server Name]" & VbCrLf
WScript.Echo "Sample: cscript.exe InstallLicense.vbs " & """MyFileServer"""
WScript.Quit
End If

sServerName = WScript.Arguments(0)

On Error Resume Next

'Connect to server agent and install license key

Set oV2iAuto = CreateObject("Symantec.ProtectorAuto")
Call oV2iAuto.Connect(sServerName)

If Err.Number <> 0 Then

Err.Clear
WScript.Echo sServerName & ":" & " Connection Failed...skipping this server"

Else

Call oV2iAuto.InstallLicense(sLicenseKey)

If Err.Number <> 0 Then

Err.Clear
WScript.Echo sServerName & ":" & " Problem installing License Key."

Else

WScript.Echo sServerName & ":" & " Successful License Key Installation"

End If

End If

Set oV2iAuto = Nothing

'================================================================================

'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

'InstallLicenseMulti.vbs

' Sample usage: Cscript.exe InstallLicense.vbs "D:\Scripted-Tasks\ServerList.txt"

' If the script and list file are in the same folder, there is no need to specify
' the path to the list file in the command line arguments

' When creating the text file containg the server names, put each server name
' on its own line.

Option Explicit

Dim sServerName, sLicenseKey
Dim sListFile, sNextLine
Dim iLoopCounter
Dim oV2iAuto, oFSO, oArguments
Dim oDictionary, oDictItem, oTextFile

Const ForReading = 1

' Clear errors before proceeding
'
Err.Clear

'Set License Key -- Omit dashes when editing this variable

sLicenseKey = "0000000000000000"

'Set Server Name

If (WScript.Arguments.Count < 1) Then
WScript.Echo "Usage: cscript.exe InstallLicense.vbs [Server List File]" & VbCrLf
WScript.Echo "Sample: cscript.exe InstallLicense.vbs " & """D:\Scripted-Tasks\ServerList.txt"""
WScript.Quit
End If

Set oArguments = WScript.Arguments

Set oDictionary = CreateObject("Scripting.Dictionary")
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oTextFile = oFSO.OpenTextFile(oArguments(0), ForReading)

iLoopCounter = 0

Do While oTextFile.AtEndOfStream <> True

sNextLine = oTextFile.Readline
oDictionary.Add iLoopCounter, sNextLine
iLoopCounter = iLoopCounter + 1

Loop

'Create the BESR automation object

Set oV2iAuto = CreateObject("Symantec.ProtectorAuto")

'Iterate through server list

For Each oDictItem in oDictionary
sServerName = oDictionary.Item(oDictItem)

'Connect to server agent and install license key

On Error Resume Next

Call oV2iAuto.Connect(sServerName)

If Err.Number <> 0 Then

Err.Clear
WScript.Echo sServerName & ":" & " Connection Failed...skipping this server"

Else

Call oV2iAuto.InstallLicense(sLicenseKey)

If Err.Number <> 0 Then

Err.Clear
WScript.Echo sServerName & ":" & " Problem installing License Key."

Else

WScript.Echo sServerName & ":" & " Successful License Key Installation"

End If

End If

Next

Set oV2iAuto = Nothing
Set oFSO = Nothing
Set oArguments = Nothing
Set oDictionary = Nothing
Set oDictItem = Nothing
Set oTextFile = Nothing