I have different things setup related to Bitlocker:
BitlockerStatus
Custom Inventory thats gets infos if Drive C and D have bitlocker enabled.
BitlockerKeys
Custom Inventory that gathers the BitlockerKeys from Drive C and D (and History enabled for this table)
I assume you just need BitlockerStatus, I created it like that:
1. Custom Inventory
1.1 Settings -> All Settings -> Discovery and Inventory -> Inventory Solution -> Manage Custom Data Classes
1.2 *New data class: I called it "H_Bitlocker_Status" with following attributes: BitlockerDriveCEnabled and BitlockerDriveDEnabled
configured like: Data type = int, Maximum size = 4, Key = No, Data required = No (do not enable "multi rows")
1.2 Save it, Click on the created Data class and click the property button to note the GUID
2. Gather Task
replace the "myDataClass" GUID with your
2.1 Create a Task (vbscript) - with the configuration you like (Hidden....)
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2\Security\MicrosoftVolumeEncryption")
Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_EncryptableVolume",,48)
'Here, the assumption is that the data class with below guid is already configured on server.
myDataClass = "{b4b65e2c-80ea-486d-8c1f-55e316b91cfc}"
'========================================================================================
'Create instance of Altiris NSE component
dim nse
set nse = WScript.CreateObject ("Altiris.AeXNSEvent")
' Set the header data of the NSE
' Please don't modify this GUID
nse.To = "{1592B913-72F3-4C36-91D2-D4EDA21D2F96}"
nse.Priority = 1
'Create Inventory data block.
dim objDCInstance
set objDCInstance = nse.AddDataClass (myDataClass)
dim objDataClass
set objDataClass = nse.AddDataBlock (objDCInstance)
'Add a new row
dim objDataRow
set objDataRow = objDataClass.AddRow
Dim arEncryptionMethod
arEncryptionMethod = Array("None", "AES 128 With Diffuser", "AES 256 With Diffuser", "AES 128", "AES 256")
Dim arProtectionStatus
arProtectionStatus = Array("Protection Off", "Protection On", "Protection Unknown")
Dim arConversionStatus
arConversionStatus = Array("Fully Decrypted", "Fully Encrypted", "Encryption In Progress", "Decryption In Progress", "Encryption Paused", "Decryption Paused")
Dim arLockStatus
arLockStatus = Array("Unlocked", "Locked")
For Each objItem in colItems
Dim EncryptionMethod
Dim ProtectionStatus
Dim ConversionStatus
Dim EncryptionPercentage 'Percentage of the volume that is encrypted
Dim VolumeKeyProtectorID
Dim LockStatus
objItem.GetEncryptionMethod EncryptionMethod
objItem.GetProtectionStatus ProtectionStatus
objItem.GetConversionStatus ConversionStatus, EncryptionPercentage
objItem.GetKeyProtectors 0,VolumeKeyProtectorID
objItem.GetLockStatus LockStatus
if objItem.DriveLetter = "C:" Then
if arProtectionStatus(ProtectionStatus) = "Protection On" then
objDataRow.SetField 0, 1
else
objDataRow.SetField 0, 0
End If
End If
if objItem.DriveLetter = "D:" Then
if arProtectionStatus(ProtectionStatus) = "Protection On" then
objDataRow.SetField 1, 1
else
objDataRow.SetField 1, 0
End If
End If
next
nse.SendQueued
3. Policy
3.1 Create a Policy to do the Custom Inventory with a Schedule that you like
You may just have a C Drive or different letters, so some adjust maybe must be made.
Hope this helps and I didn't forget a step