I am also using the WinPE2.1 exe in my PXE config.
Do I need to install the AIK ? and then use the script within the Dell toolkit folder to inject the drivers into the base winpe.wim
script
@echo off
:: ***************************************************************************
:: * WARRANTY DISCLAIMER
:: ***************************************************************************
:: * THIS SCRIPT IS BEING PROVIDED TO YOU "AS IS". DELL DISCLAIMS ANY
:: * AND ALL WARRANTIES, EXPRESS, IMPLIED OR STATUTORY, WITH RESPECT TO THE
:: * SCRIPT, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
:: * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE, TITLE AND ANY WARRANTY
:: * OF NON-INFRINGEMENT. YOU WILL USE THIS SCRIPT AT YOUR OWN RISK.
:: * DELL SHALL NOT BE LIABLE TO YOU FOR ANY DIRECT OR INDIRECT DAMAGES
:: * INCURRED IN USING THE SCRIPT. IN NO EVENT SHALL DELL OR ITS
:: * SUPPLIERS BE RESPONSIBLE FOR ANY DIRECT OR INDIRECT DAMAGES WHATSOEVER
:: * (INCLUDING, WITHOUT LIMITATION, DAMAGES FOR LOSS OF PROFITS, LOSS OF USE,
:: * LOSS OF DATA, BUSINESS INTERRUPTION, OR OTHER PECUNIARY LOSS, NOR FOR
:: * PUNITIVE, INCIDENTAL, CONSEQUENTIAL, OR SPECIAL DAMAGES OF ANY KIND,
:: * UNDER ANY PART OF THIS AGREEMENT, EVEN IF ADVISED OR AWARE OF THE
:: * POSSIBILITY OF SUCH DAMAGES).
:: ***************************************************************************
:: ***************************************************************************
REM Name: VPE_driverinst.bat
REM
REM Purpose:
REM This script installs Dell drivers into a base Windows PE 2.0 image offline.
REM Most of these drivers are essential for DTK tools to work correctly.
REM
REM Arguments:
REM %1 Path to local directory for Windows PE 2.0
REM %2 Path to extracted DTK toolkit
:: ***************************************************************************
if "%1%" == "" goto usage
if "%2%" == "" goto usage
Set AIKTOOLS="C:\Program files\Windows AIK\Tools"
@echo ---------------------------------------
@echo ~~1(VPE_driverinst.bat)-Check the Paths
@echo ----------------------------------------
if not exist %2% (
echo DTKPATH %2% does not exist. Exiting.....
goto done
)
if not exist %AIKTOOLS% (
echo %AIKTOOLS% does not exist. Exiting.....
goto done
)
REM WINPEPATH is the Path to the WinPE 2.0
Set WINPEPATH=%1%
Set DTKPATH=%2%
echo %WINPEPATH%
echo %DTKPATH%
@echo ------------------------------------
@echo ~~2-Setup a WinPE 2.0 build environment
@echo -------------------------------------
::rd /s/q %WINPEPATH%
if not exist %WINPEPATH% call %AIKTOOLS%\PETools\copype.cmd x86 %WINPEPATH%
@echo --------------------------------------------
@echo ~~3-Mount the base WinPE Image (winpe.wim)
@echo --------------------------------------------
REM Mount the base WINPE image (1=Image Number) locally to add or remove packages
%AIKTOOLS%\x86\imagex /mountrw %WINPEPATH%\WinPE.wim 1 %WINPEPATH%\mount\
REM List the packages in the base WinPE Image
%AIKTOOLS%\PETools\peimg /list %WINPEPATH%\mount\windows
@echo ------------------------------------
@echo ~~4-Add additional customizations
@echo ------------------------------------
REM Add Windows WMI package
%AIKTOOLS%\PETOOLS\peimg /install=WinPE-WMI-Package %WINPEPATH%\mount\Windows
REM Add ImageX
copy %AIKTOOLS%\x86\imagex.exe %WINPEPATH%\iso\
copy %AIKTOOLS%\x86\imagex.exe %WINPEPATH%\mount\Windows\system32
REM Add Package Manager(Pkgmgr.exe) AND MSXML6 binaries
xcopy %AIKTOOLS%\x86\Servicing\*.* %WINPEPATH%\iso\Servicing /S /E /i /Y
xcopy %windir%\system32\msxml6*.dll %WINPEPATH%\iso\Servicing /Y /i
@echo -----------------------------------------------
@echo ~~5-Add Dell Drivers to the mounted Image
@echo -----------------------------------------------
:: Add the .inf file to the base image - Repeat this for each driver
%AIKTOOLS%\PETOOLS\peimg /inf=%DTKPATH%\winpe2.x\massstorage\PERC5-6\*.inf %WINPEPATH%\mount\Windows
%AIKTOOLS%\PETOOLS\peimg /inf=%DTKPATH%\winpe2.x\massstorage\SAS5-6\*.inf %WINPEPATH%\mount\Windows
:: %AIKTOOLS%\PETOOLS\peimg /inf=%DTKPATH%\winpe1.x\rac4\*.inf %WINPEPATH%\mount\Windows
:: %AIKTOOLS%\PETOOLS\peimg /inf=%DTKPATH%\winpe2.x\BCM-Driver\win_xp_2k3_32\*.inf %WINPEPATH%\mount\Windows
%AIKTOOLS%\PETOOLS\peimg /inf=%DTKPATH%\winpe2.x\nic\Broadcom\*.inf %WINPEPATH%\mount\Windows
%AIKTOOLS%\PETOOLS\peimg /inf=%DTKPATH%\winpe2.x\nic\Intel\*.inf %WINPEPATH%\mount\Windows
@echo -------------------------------------------------------------
@echo ~~6-Copy RADICFG, HAPI and TOOLKIT Files to the mounted image
@echo --------------------------------------------------------------
copy /Y %DTKPATH%\common\raidcfg\*.dll %WINPEPATH%\mount\Windows\System32
copy /Y %DTKPATH%\common\hapi\*.dll %WINPEPATH%\mount\Windows\System32
copy /Y %DTKPATH%\common\hapi\*.sys %WINPEPATH%\mount\Windows\System32\Drivers
xcopy %DTKPATH%\..\Toolkit\*.* %WINPEPATH%\mount\Dell\Toolkit /S /E /i /Y
::@echo ---------------------------------------
::@echo ~~7-Copy iSCSI Files to WINPE Folder
::@echo ---------------------------------------
::copy /Y %DTKPATH%\winpe2.x\iSCSI\iscsicpl.cpl %WINPEPATH%\mount\Windows\System32
::copy /Y %DTKPATH%\winpe2.x\iSCSI\*.dll %WINPEPATH%\mount\Windows\System32
::copy /Y %DTKPATH%\winpe2.x\iSCSI\*.exe %WINPEPATH%\mount\Windows\System32
::copy /Y %DTKPATH%\winpe2.x\iSCSI\*.sys %WINPEPATH%\mount\Windows\System32
::mkdir %WINPEPATH%\mount\Windows\iscsi
::copy /Y %DTKPATH%\winpe2.x\iSCSI\*.cat %WINPEPATH%\mount\Windows\iscsi
::copy /Y %DTKPATH%\winpe2.x\iSCSI\iscsilog.dll %WINPEPATH%\mount\Windows\iscsi
::copy /Y %DTKPATH%\winpe2.x\iSCSI\*.inf %WINPEPATH%\mount\Windows\iscsi
::copy /Y %DTKPATH%\winpe2.x\iSCSI\*.mof %WINPEPATH%\mount\Windows\iscsi
::copy /Y %DTKPATH%\winpe2.x\iSCSI\*.sys %WINPEPATH%\mount\Windows\iscsi
@echo -----------------------------------------------
@echo ~~8-Merge HAPI registry entries in System-Hive
@echo ------------------------------------------------
REM Winpe.wim must be mounted at this point !
reg load HKLM\Hiv %WINPEPATH%\mount\Windows\System32\config\system
reg import %DTKPATH%\common\hapi\dellreg\hapiservice.reg
reg import %DTKPATH%\common\hapi\dellreg\hapienum.reg
::reg import %DTKPATH%\winpe2.x\iSCSI\reg\WinPEiSCSI.reg
reg unload HKLM\Hiv
@echo ------------------------
@echo ~~9-Add the Services
@echo ------------------------
::echo net start msiscsi >> %WINPEPATH%\mount\windows\system32\STARTNET.CMD
echo echo Starting WMI Services >> %WINPEPATH%\mount\windows\system32\STARTNET.CMD
echo net start winmgmt >> %WINPEPATH%\mount\windows\system32\STARTNET.CMD
@echo ------------------------
@echo ~~9.1-RAC4
@echo ------------------------
echo drvload.exe X:\Dell\Toolkit\Tools\RAC4\rac4ser.inf >> %WINPEPATH%\mount\windows\system32\STARTNET.CMD
copy /Y %DTKPATH%\..\Toolkit\Tools\rac4\racsvc.exe %WINPEPATH%\mount\Windows\system32
echo echo Starting RAC Service >> %WINPEPATH%\mount\windows\system32\STARTNET.CMD
echo racsvc -install >> %WINPEPATH%\mount\windows\system32\STARTNET.CMD
::@echo ------------------------
::@echo ~~10-iSCSI NIC drivers
::@echo ------------------------
::%AIKTOOLS%\PETOOLS\peimg /inf=%DTKPATH%\winpe2.x\nic\Broadcom\*.inf %WINPEPATH%\mount\Windows
::xcopy %DTKPATH%\..\Toolkit\Tools\iscsi\Broadcom\iscsi_config\ipxyd.sys %WINPEPATH%\mount\Windows\System32\Drivers
::xcopy %DTKPATH%\..\Toolkit\Tools\iscsi\Intel\*.sys %WINPEPATH%\mount\Windows\System32\Drivers
@echo -------------------------------------
@echo ~~11-Prepare the image for deployment
@echo --------------------------------------
%AIKTOOLS%\PETOOLS\peimg.exe /prep %WINPEPATH%\mount\Windows /f
@echo ---------------------------------------------
@echo ~~12-Commit the customization to base image
@echo ---------------------------------------------
::Commit Changes to the Standard Image (winpe.wim)
%AIKTOOLS%\x86\imagex.exe /unmount /commit %WINPEPATH%\mount\
goto done
:usage
echo.
echo VPE_driverinst.bat
echo.
echo Copyright (c) 2007 Dell Inc.
echo.
echo Usage : VPE_driverinst.bat WINPEPATH DTKPATH
echo
echo Where:
echo WINPEPATH path where the Windows PE 2.0 contents are located
echo DTKPATH path where Dell-provided drivers are located
echo.
echo Example: VPE_driverinst.bat C:\vistaPE_x86 D:\DELL\DRIVERS
echo This installs the RAC4, NIC, RAIDCFG, MASS-STORAGE and HAPI (Instrumentation)
echo drivers found in the D:\DELL\Drivers folder to the base Windows PE image
echo in C:\vistaPE_x86.
echo.
echo NOTE: If any of these drivers are already present in the Windows PE Image,
echo then this script overwrites them.
echo.
goto done
:done
@echo -------------------------------
@echo ~~12(VPE_driverinst.bat)-DONE.
@echo -------------------------------
set WINPEPATH=
set DTKPATH=
set AIKTOOLS=
echo.