Are you replacing Normal.dot when you install your application? Are you backing up the old version of Normal.dot?

I would suggest that restoring the old version of Normal.dot would be the best strategy, but this file is locked whenever Word is running, so replacing it with the previous version would require use of the PendingFileRenameOperations registry key and a reboot. Alternatively, you could add a command to the runonce registry key, to copy the old normal.dot over the existing one, as the machine is started, and before Word gets loaded.

Hi VBScab,

  Thanks for your assistance, I recorded a macro and it works fine when I run it from vba editor. But  all I got is this code, and I am not getting how to use this macro separately on different machines.

Sub Macro1()
'
' Macro1 Macro
' remove bull
'
    Application.OrganizerDelete Source:= _
        "C:\USERS\USERINF\MSOFFICE\TEMPLATE\NORMAL.DOT", Name:="Bullfighter", _
        Object:=wdOrganizerObjectCommandBars
End Sub

The 'Application' keyword can be replaced with the name of the Word Application object which you would create in the script. You also need to use the Object Browser in the VBA Editor (press F2) to find out what value the variable 'wdOrganizerObjectCommandBars' has. Look at the Word object in the Object Browser, select 'Globals' in the 'Classes' list, then scroll the right-hand pane down to 'wdOrganizerObjectCommandBars'. Click that once and its value will be shown just above the 'Immediate' window. Most stand-alone variables like this have the value '0' (zero) but check.

So, assuming it's zero, you might end up with (STILL no <code> tag in this wretched forum...):
<code>
Option Explicit

Dim objWord
Dim strTemplatePath
Dim strTemplateName
Dim strAddInName

Const wdOrganizerObjectCommandBars = 0

strTemplatePath        = "C:\USERS\USERINF\MSOFFICE\TEMPLATE"
strTemplateName        = "NORMAL.DOT"
strAddInName        = "Bullfighter"

'// First things first - can we create a Word object? No sense continuing if not...
On Error Resume Next
Set objWord         = CreateObject("Word.Application")
On Error Goto 0

If Not IsObject(objWord) Then
    WScript.Quit(False)
End If

Call RemoveAddIn(strTemplatePath, strTemplateName, strAddInName)

Set objWord         = Nothing

Sub RemoveAddIn(ByVal strTemplateFolder, ByVal strTemplateTarget, ByVal strAddIn)

    Dim strTemplate
    '// The purpose of having separate path and name for the template is
    '// to allow you to add error-trapping code, e.g. to test for the
    '// existence of the path and the template
   
    '//Once we're happy that the path and template exist, build an easier-to-read variable
    strTemplate    = strTemplateFolder & "\" & strTemplateTarget
   
    objWord.OrganizerDelete Source:=strTemplate, Name:=strAddInName, Object:=wdOrganizerObjectCommandBars
   
    '// Worth adding a check - somehow - to check whether it got deleted.
    '// Perhaps there's an means to enumerate add-ins?
End Sub
</code>Please note that this is stream-of-consciousness code and completely untested.

Lastly, always, ALWAYS make a back-up of NORMAL.DOT and, if possible, avoid adding add-ins (and other junk like styles) to that template in the first place. If (sorry, when) it breaks, Word is screwed.

Option Explicit

Dim objWord
Dim strTemplatePath
Dim strTemplateName
Dim strAddInName
Dim oshell,SD
Set oshell=CreateObject("Wscript.shell")
SD=oshell.ExpandEnvironmentStrings("%SYSTEMDRIVE%")

Const wdOrganizerObjectCommandBars = 2
'Set objwdobject = CreateObject("Word.WdOrganizerObjectCommandBars")

strTemplatePath        = SD & "\" & "Users\USERINF\MSOFFICE\TEMPLATE"
strTemplateName        = "NORMAL.DOT"
strAddInName        = "Bullfighter"

On Error Resume Next
Set objWord         = CreateObject("Word.Application")
On Error Goto 0

If Not IsObject(objWord) Then
    WScript.Quit(False)
End If
objWord.Visible=True
Call RemoveAddIn(strTemplatePath, strTemplateName, strAddInName)

Set objWord         = Nothing

   
Sub RemoveAddIn(ByVal strTemplateFolder, ByVal strTemplateTarget, ByVal strAddIn)
    Dim strTemplate
    strTemplate    = strTemplateFolder & "\" & strTemplateTarget
    objWord.documents.open(strTemplate)
    objWord.OrganizerDelete strTemplate,strAddInName,wdOrganizerObjectCommandBars
    objWord.quit true
End Sub

Thanks for sharing your code with us

Add some traps to RemoveAddIn so that you can be sure the path and file exist.

The Golden Rule in programming is: Assume Nothing.

Also, it's much neater to use the With keyword when you have to use an object over and over. It saves the interpreter (let's call it) from having to continuously fetch the object pointer:
<code>
With objWord
   .documents.open(strTemplate)
   .OrganizerDelete strTemplate,strAddInName,wdOrganizerObjectCommandBars
   .Quit true
End With
</code>

Any program you have coded will always error out in a scenario that your error handling has not allowed for. The more error handling you include from day 1, the less chance of unexplained crashes.