'==========================================================================
' VBScript to execute a known SWD Advertisement provided on the command line
'==========================================================================
Option Explicit
On Error Resume Next

Dim oArgs, sAdvertisementGuid
Dim oAltiris, oAeXSWDAgent, oShell
Set oAltiris = CreateObject("Altiris.AeXNSClient")
Set oShell = CreateObject("WScript.Shell")
Set oAeXSWDAgent = oAltiris.ClientPolicyMgr.ClientAgent("Altiris.SWD")
Set oArgs = WScript.Arguments ' command-line options

sAdvertisementGuid = oArgs(0)

If Left(sAdvertisementGuid, 1) <> "{" Then sAdvertisementGuid = "{" & sAdvertisementGuid 
If Right(sAdvertisementGuid, 1) <> "}" Then sAdvertisementGuid = sAdvertisementGuid  & "}"
If Len(sAdvertisementGuid) <> 38 Then
	MsgBox "Invalid command line argument: " & sAdvertisementGuid & "." & VbCrLf & _
	    VbCrLf & "Correct usage is: " & VbCrLf & "Wscript.exe """ & WScript.ScriptFullName & _
	    """ {Task Guid}," & VbCrLf & VbCrLf & "where <Task Guid> is formatted as 12345678-1234-1234-1234-123456789ABC," & _
	    VbCrLf & "with or without {} around the advertisement GUID.", vbOKOnly+vbCritical+vbSystemModal, _
		"Incorrect command line!"
Else
	oShell.Popup "Executing Altiris task identifier: " & sAdvertisementGuid, 5, "Executing Altiris task...", _
		vbOKOnly+vbSystemModal+vbInformation
	oAltiris.SendBasicInventory True, True
	oAltiris.UpdatePolicies True
	Err.Clear
	oAeXSWDAgent.RunAdvertisement sAdvertisementGuid, 0
	WScript.Sleep 2000
	If Err.Number <> 0 Then
		MsgBox "The specified task returned an error code: " & Err.Number & VbCrLf & VbCrLf & _
			"Error description: " & Err.Description, vbOKOnly+vbCritical+vbSystemModal, "Task execution returned an error" 
	End If
End If
Set oAeXSWDAgent = Nothing
Set oAltiris = Nothing
Set oArgs = Nothing

WScript.Quit(Err.Number)